PackageTop Level
Classpublic dynamic class Error
InheritanceError Inheritance Object
Subclasses ArgumentError, DefinitionError, EvalError, IllegalOperationError, InvalidSWFError, IOError, MemoryError, RangeError, ReferenceError, ScriptTimeoutError, SecurityError, StackOverflowError, SyntaxError, TypeError, URIError, VerifyError

Language Version: ActionScript 3.0
Runtime Versions:  1.0, 9

The Error class contains information about an error that occurred in a script. In developing ActionScript 3.0 applications, when you run your compiled code in the debugger version of Flash Player, a dialog box displays exceptions of type Error, or of a subclass, to help you troubleshoot the code. You create an Error object by using the Error constructor function. Typically, you throw a new Error object from within a try code block that is caught by a catch or finally code block.

You can also create a subclass of the Error class and throw instances of that subclass.

View the examples

See also

Working with the debugger version of Flash Player
Creating custom error classes
Responding to error events and status

Public Properties
 PropertyDefined By
 Inheritedconstructor : Object
A reference to the class object or constructor function for a given object instance.
Object
  errorID : int
[read-only] Contains the reference number associated with the specific error message.
Error
  message : String
Contains the message associated with the Error object.
Error
  name : String
Contains the name of the Error object.
Error
 Inheritedprototype : Object
[static] A reference to the prototype object of a class or function object.
Object
Public Methods
 MethodDefined By
  
Error(message:String = "", id:int = 0)
Creates a new Error object.
Error
  
getStackTrace():String
Returns the call stack for an error as a string at the time of the error's construction (for the debugger version of Flash Player only).
Error
 Inherited
hasOwnProperty(name:String):Boolean
Indicates whether an object has a specified property defined.
Object
 Inherited
isPrototypeOf(theClass:Object):Boolean
Indicates whether an instance of the Object class is in the prototype chain of the object specified as the parameter.
Object
 Inherited
propertyIsEnumerable(name:String):Boolean
Indicates whether the specified property exists and is enumerable.
Object
 Inherited
setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void
Sets the availability of a dynamic property for loop operations.
Object
  
toString():String
Returns the string "Error" by default or the value contained in Error.message property, if defined.
Error
 Inherited
valueOf():Object
Returns the primitive value of the specified object.
Object
Property Detail
errorIDproperty
errorID:int  [read-only]

Language Version: ActionScript 3.0
Runtime Versions:  1.0, 9

Contains the reference number associated with the specific error message. For a custom Error object, this number is the value from the id parameter supplied in the constructor.



Implementation
    public function get errorID():int
messageproperty 
public var message:String

Language Version: ActionScript 3.0
Runtime Versions:  1.0, 9

Contains the message associated with the Error object. By default, the value of this property is " Error ". You can specify a message property when you create an Error object by passing the error string to the Error constructor function.

See also

statements.html#throw
statements.html#try..catch..finally
nameproperty 
public var name:String

Language Version: ActionScript 3.0
Runtime Versions:  1.0, 9

Contains the name of the Error object. By default, the value of this property is " Error ".

See also

statements.html#throw
statements.html#try..catch..finally
Constructor Detail
Error()Constructor
public function Error(message:String = "", id:int = 0)

Language Version: ActionScript 3.0
Runtime Versions:  1.0, 9

Creates a new Error object. If message is specified, its value is assigned to the object's Error.message property.

Parameters
message:String (default = "") — A string associated with the Error object; this parameter is optional.
 
id:int (default = 0) — A reference number to associate with the specific error message.

See also

statements.html#throw
statements.html#try..catch..finally

Example

The following example creates a new Error object err and then, using the Error() constructor, assigns the string "New Error Message" to err . 
var err:Error = new Error();
trace(err.toString());    // Error

err = new Error("New Error Message");
trace(err.toString());    // Error: New Error Message
Method Detail
getStackTrace()method
public function getStackTrace():String

Language Version: ActionScript 3.0
Runtime Versions:  1.0, 9

Returns the call stack for an error as a string at the time of the error's construction (for the debugger version of Flash Player only). As shown in the following example, the first line of the return value is the string representation of the exception object, followed by the stack trace elements: 

TypeError: null cannot be converted to an object
      at com.xyz.OrderEntry.retrieveData(OrderEntry.as:995)
      at com.xyz.OrderEntry.init(OrderEntry.as:200)
      at com.xyz.OrderEntry.$construct(OrderEntry.as:148)

Returns
String — A string representation of the call stack.
toString()method 
override public function toString():String

Language Version: ActionScript 3.0
Runtime Versions:  1.0, 9

Returns the string "Error" by default or the value contained in Error.message property, if defined.

Returns
String — The error message.

See also

Error.message
statements.html#throw
statements.html#try..catch..finally

Example

The following example creates a new Error object err and then, using the Error() constructor, assigns the string "New Error Message" to err . Finally, the message property is set to "Another New Error Message" , which overwrites "New Error Message" . 
var err:Error = new Error();
trace(err.toString());    // Error

err = new Error("New Error Message");
trace(err.toString());    // Error: New Error Message

err.message = "Another New Error Message";
trace(err.toString());    // Error: Another New Error Message
Examples How to use examples

The following example uses the ErrorExample class to show how a custom error can be generated. This is accomplished with the following steps:
  1. A local variable nullArray of Array type is declared, but notice that a new Array object is never created.
  2. The constructor attempts to load a value into the uninitialized array by using the push() method within an error handling code segment that catches a custom error by using the CustomError class, which extends Error .
  3. When the CustomError is thrown, the constructor catches it and then outputs an error message by using the trace() statement. 
package
{
    import flash.display.Sprite;
    public class ErrorExample extends Sprite 
    {
        private var nullArray:Array;
        public function ErrorExample() 
        {
            try 
            {
                nullArray.push("item");
            }
            catch(e:Error) 
            {
                throw new CustomError("nullArray is null");
            }
        }
    }
}

class CustomError extends Error 
{
    public function CustomError(message:String) 
    {
        super(message);
    }
}



Submit Feedback on LiveDocs
© 2004-2008 Adobe Systems Incorporated. All rights reserved.
Sun Oct 19 2008, 07:03 PM -07:00